* To duplicate results in the paper using the file made publicly available, 
* run the following commands in Stata.
*
* Change directory to the correct directory first.
*
* Results are duplicated below for table 5 in the paper.
*   Corrections to exityr and entryyr below account for dating on the cover of Thomas' Register
*   compared to the actual publication dates.  This is a rather esoteric topic, but here is a brief
*   overview:
*     In some years, Thomas' Register's cover date was 1 greater than the publication date (e.g., 
*     it said on the cover 1937 when it was published in December 1936 and hence has information
*     representative of 1936),
*     but in other years, Thomas' Register's cover date was the same as the publication date (e.g.,
*     it said 1922 when it was published in July 1922).
*     This is complicated by the fact that some dates were indicated on the cover showing two years, 
*     like "1909/10" or "1927-28", in which case a particular one of the years was coded when entering 
*     data.
*     The data in the cordtires.txt file had not been corrected for some of these issues, hence the
*     correction here.
* Log likelihoods in the paper will be offset by a constant factor from what is reported by Stata.
*   (An earlier version of Stata would give different log likelihoods after splitting the data into
*   time periods, and as I recall, this is how the difference arose.)
*
* Kenneth L. Simons, 14 Sept. 2006
*
insheet using "cordtires.txt", clear
replace exityr = exityr - 1 if exityr >= 1934
replace entryyr = entryyr - 1 if (entryyr >= 1912 & entryyr <= 1914) | entryyr==1920 | entryyr==1921
gen byte aaaa = trsize20 >= 1000
gen byte x = trsize20 < 1
gen byte mid = 1 - aaaa - x
gen em1900 = entryyr-1900
gen xt = exityr - 1921
gen byte censor = exityr>=1980
gen byte fail = !censor
gen int id = _n
stset xt, id(id) failure(fail)
stsum
stdes
stsplit timecat, at(3 6 15 25)
tab timecat
gen byte y1 = timecat==0
gen byte y2 = timecat==3
gen byte y3 = timecat==6
gen byte y4 = timecat==15
gen byte y5 = timecat==25
streg y1 y2 y3 y4 y5 em1900, dist(exp) nohr nocons
streg y1 y2 y3 y4 y5 em1900 akron aaaa mid , dist(exp) nohr nocons